site içi arama motoru

asuozkan · 15/11/2003, 19:17

site içi arama motoru yapmam gerekiyor.nasil yapildigi konusunda yardimci olabilir misiniz

HunTER · 15/11/2003, 19:34

1. Sıtede kullanılan sunucu taraflı bı scrıpt dılı varmı? Varsa hangısı (ASP,PHP vs..)
2. Icınde arama yapılacak verı nerde tutuluyor? Web sayfalarında? Verıtabanında? Her ıkısı ve daha fazlası?
3. Krıterler neler? Tek sozcuk arama? Bırden fazla sozcuk arama?
4. Yada sadece google uzerınden arama ısıne yaramazmı?.. Ornegın
http://www.google.com.tr/search?q=ph...:www.ceviz.net gıbı

Yanı once bunlara bı acıklık getırsen en azından ne yapabılecegın konusunda tavsıye verebılırız..

asuozkan · 15/11/2003, 20:31

istedigim site içi arama.veritabani yok.tek sozcuk veya birden fazla .asp konusunda cok fazla bilgim yok.

Sahin · 15/11/2003, 20:55

www.atomz.com gibi özelleştirilebilir free site içi arama motorları işinizi görür mü?

asuozkan · 17/11/2003, 11:33

site icinde arama motoru yapmam lazim.www.atomz.com isime yaramaz.tesekkurler

fixman · 17/11/2003, 12:14

MEHMET · 17/11/2003, 12:23

Geçen yıllarda bende aynı böyle bir saçma arama motoru oluşturmaya çalışıyordum olmayınca aramaya başladım. ve aşağıdaki scripti buldum gerçi doğrusunu söylemek gerekirse scriptin bayağı bir hali değişti ama artık idare edersin. İngilizce çevirileri yaparsın artık. Bu arada bu kodlar asp uzantılı sayfalarının içerisine gömülmeli.
Kolay gelsin

Alıntı:

<% Option Explicit %>
<%
'Set the response buffer to true
Response.Buffer = True

'Dimension global variables
Dim fsoObject 'File system object
Dim fldObject 'Folder object
Dim sarySearchWord 'Array to hold the words to be searched for
Dim strSearchWords 'Holds the search words
Dim blnIsRoot 'Set to true if we are searching in the root directory
Dim strFileURL 'Holds the path to the file on the site
Dim strServerPath 'Holds the server path to this script
Dim intNumFilesShown 'Holds the number of files shown so far
Dim intTotalFilesSearched 'Holds the number of files searched
Dim intTotalFilesFound 'Holds the total matching files found
Dim intFileNum 'Holds the file number
Dim intPageLinkLoopCounter 'Loop counter to display links to the other result pages
Dim sarySearchResults(500,2) 'Two Dimensional Array holding the search results
Dim intDisplayResultsLoopCounter 'loop counter to diplay the results of the search
Dim intResultsArrayPosition 'Stores the array position of the array storing the results
Dim blnSearchResultsFound 'Set to true if search results are found
Dim strFilesTypesToSearch 'Holds the types of files to be searched
Dim strBarredFolders 'Holds the folders that you don't want searched
Dim strBarredFiles 'Holds the names of the files not to be searched

' -------------------------- Change the following line to the number of results you wish to have on each page ------------------------------------

Const intRecordsPerPage = 10 'cahnge this to the number of results to show on each page

' --------------------- Place the names of the files types you want searching in the following line sepeararted by commas --------------------------

strFilesTypesToSearch = "htm,html,asp,shtml"

' --------------------- Place the names of the folders you don't want searched in the following line spearated by commas --------------------------

strBarredFolders = "cgi_bin,_private" 'cgi_bin and _private have been put in here as examples, but you can put any folders in here

' ---------- Place the names of the files you don't want searched in the following line spearated by commas include the file extension -------------

strBarredFiles = "adminstation.htm,no_allowed.asp" 'adminstration.htm and not_allowed.asp have been put in as an examples

'-----------------------------------------------------------------------------------------------------------------------------------------------------

'Initalise variables
intTotalFilesSearched = 0

%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-9">
<title>Site içi arama</title>
<meta name="KeyWords" content="Site içi Arama">


<script language="JavaScript">

</script>

</head>
<body bgcolor="#330099" text="#FFFFFF" link="#66CCFF" vlink="#66CCFF" alink="#FF0000">
<h1 align="center">Siteiçi Arama</h1>

<form method="get" name="frmSiteSearch" action="site_search.asp" onSubmit="return CheckForm();">
<table cellpadding="0" cellspacing="0" width="90%" align="center">
<tr>
<td height="66" width="15" align="right" rowspan="3" valign="middle"> </td>
<td class="arial" height="4" width="571"> websitede Arama: </td>
</tr>
<tr>
<td class="normal" height="2" width="571">
<input type="TEXT" name="search" maxlength="50" size="36" value="<% =Request.QueryString("search") %>">
<input type="submit" value="ARA>>" name="submit">
</td>
</tr>
<tr>
<td class="normal" height="34" width="571" valign="top"> Aranacak :
<input type="radio" name="mode" value="allwords" CHECKED> Sözcüklerin
Hepsi
<input type="radio" name="mode" value="anywords"> Sözcüklerin Herhangi
biri
<input type="radio" name="mode" value="phrase"> Aynen girildiği gibi</td>
</tr>
</table>
</form>

<%

'Read in all the search words into one variable
strSearchWords = Trim(Request.QueryString("search"))

'Replace any HTML tags with the HTML codes for the same characters (stops people entering HTML tags)
strSearchWords = Server.HTMLEncode(strSearchWords)

'Slit each word to be searched up and place in an array
sarySearchWord = Split(Trim(strSearchWords), " ")

'Read the file number to show from
intFileNum = CInt(Request.QueryString("FileNumPosition"))

'Set the number of files shown so far to the file number read in above
intNumFilesShown = intFileNum

'Create the file system object
Set fsoObject = Server.CreateObject("Scripting.FileSystemObject")

'If there is no words entered by the user to search for then dont carryout the file search routine
If NOT Request.QueryString("search") = "" Then

'Get the path and the root folder to be searched
Set fldObject = fsoObject.GetFolder(Server.MapPath("./"))

'Read in the server path to this ASP script
strServerPath = fldObject.Path & "\"

'Set to true as this is searching the root directory
blnIsRoot = True

'Call the search sub prcedure
Call SearchFile(fldObject)

'Reset server variables
Set fsoObject = Nothing
Set fldObject = Nothing

'Call the Bubble Sort procedure to sort the results into highest matches first
Call SortResultsByNumMatches(sarySearchResults, intTotalFilesFound)

'Display the HTML table with the results status of the search or what type of search it is
Response.Write vbCrLf & " <table width=""98%"" border=""0"" cellspacing=""1"" cellpadding=""1"" align=""center"" bgcolor=""#333399"">"
Response.Write vbCrLf & " <tr>"

'Display that there where no matching records found
If blnSearchResultsFound = False Then
Response.Write vbCrLf & " <td> Searched the site for <b>" & strSearchWords & "</b>.    Sorry, no results found.</td>"

'Else Search went OK so display how many records found
Else
Response.Write vbCrLf & " <td> Searched the site for <b>" & strSearchWords & "</b>.    Displaying Results " & intFileNum + 1 & " - " & intNumFilesShown & " of " & intTotalFilesFound & ".</td>"
End If

'Close the HTML table with the search status
Response.Write vbCrLf & " </tr>"
Response.Write vbCrLf & " </table>"

'HTML table to display the search results or an error if there are no results
Response.Write vbCrLf & " <table width=""95%"" border=""0"" cellspacing=""1"" cellpadding=""1"" align=""center"">"
Response.Write vbCrLf & " <tr>"
Response.Write vbCrLf & " <td>"

'If no results are found then display an error message
If blnSearchResultsFound = False Then

'Write HTML displaying the error
Response.Write vbCrLf & " <br>"
Response.Write vbCrLf & " Your Search - <b>" & strSearchWords & "</b> - did not match any files on this site."
Response.Write vbCrLf & " <br><br>"
Response.Write vbCrLf & " Suggestions:"
Response.Write vbCrLf & " <br>"
Response.Write vbCrLf & " <ul><li>Make sure all words are spelled correctly.<li>Try different keywords.<li>Try more general keywords.<li>Try fewer keywords.</ul>"

'Else display the results
Else

'Loop round to display each result within the search results array
For intDisplayResultsLoopCounter = (intFileNum + 1) to intNumFilesShown

Response.Write vbCrLf & " <br>"
Response.Write vbCrLf & " " & sarySearchResults(intDisplayResultsLoopCounter,1)
Response.Write vbCrLf & " <br>"
Next
End If

'Close the HTML table displaying the results
Response.Write vbCrLf & " </td>"
Response.Write vbCrLf & " </tr>"
Response.Write vbCrLf & " </table>"

End If

'Display an HTML table with links to the other search results
If intTotalFilesFound > intRecordsPerPage then

'Display an HTML table with links to the other search results
Response.Write vbCrLf & " <br>"
Response.Write vbCrLf & " <table width=""100%"" border=""0"" cellspacing=""0"" cellpadding=""0"" align=""center"">"
Response.Write vbCrLf & " <tr>"
Response.Write vbCrLf & " <td>"
Response.Write vbCrLf & " <table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"">"
Response.Write vbCrLf & " <tr>"
Response.Write vbCrLf & " <td width=""50%"" align=""center"">"

Response.Write vbCrLf & " Results Page:  "

'If the page number is higher than page 1 then display a back link
If intNumFilesShown > intRecordsPerPage Then
Response.Write vbCrLf & " <a href=""site_search.asp?FileNumPosition=" & intFileNum - intRecordsPerPage & "&search=" & Replace(strSearchWords, " ", "+") & "&mode=" & Request.QueryString("mode") & """ target=""_self""><< Prev</a> "
End If

'If there are more pages to display then display links to all the search results pages
If intTotalFilesFound > intRecordsPerPage Then

'Loop to diplay a hyper-link to each page in the search results
For intPageLinkLoopCounter = 1 to CInt((intTotalFilesFound / intRecordsPerPage) + 0.5)

'If the page to be linked to is the page displayed then don't make it a hyper-link
If intFileNum = (intPageLinkLoopCounter * intRecordsPerPage) - intRecordsPerPage Then
Response.Write vbCrLf & " " & intPageLinkLoopCounter
Else

Response.Write vbCrLf & "  <a href=""site_search.asp?FileNumPosition=" & (intPageLinkLoopCounter * intRecordsPerPage) - intRecordsPerPage & "&search=" & Replace(strSearchWords, " ", "+") & "&mode=" & Request.QueryString("mode") & """ target=""_self"">" & intPageLinkLoopCounter & "</a>  "
End If
Next
End If

'If it is Not the last of the search results than display a next link
If intTotalFilesFound > intNumFilesShown then
Response.Write vbCrLf & "  <a href=""site_search.asp?FileNumPosition=" & intNumFilesShown & "&search=" & Replace(strSearchWords, " ", "+") & "&mode=" & Request.QueryString("mode") & """ target=""_self"">Next >></a>"
End If

'Finsh HTML the table
Response.Write vbCrLf & " </td>"
Response.Write vbCrLf & " </tr>"
Response.Write vbCrLf & " </table>"
Response.Write vbCrLf & " </td>"
Response.Write vbCrLf & " </tr>"
Response.Write vbCrLf & " </table>"

End If

%>
<br>
<div align="center">

<table width="98%" border="0" cellspacing="1" cellpadding="1" bgcolor="#333399" align="center">
<tr>
<td width="47%" height="18"> Searched <% = intTotalFilesSearched %> documents in total. </td>
</tr>
</table>
<br>
 </div>
<br>
</body>
</html>
<%

'Sub procedure to do the search
Public Sub SearchFile(fldObject)

'Dimension local variabales
Dim objRegExp 'Regular Expersions object
Dim objMatches 'Holds the matches collection of the regular expresions object
Dim filObject 'File object
Dim tsObject 'Text stream object
Dim subFldObject 'Sub folder object
Dim strFileContents 'Holds the contents of the file being searched
Dim strPageTitle 'Holds the title of the page
Dim strPageDescription 'Holds the description of the page
Dim strPageKeywords 'Holds the keywords of the page
Dim intSearchLoopCounter 'Loop counter to search all the words in the array
Dim intNumMatches 'Holds the number of matches
Dim blnSearchFound 'Set to true if the search words are found

'Error handler
On Error Resume Next

'Loop to search each file in the folder
For Each filObject in fldObject.Files

'Check the file extension to make sure the file is of the extension type to be searched
If InStr(1, strFilesTypesToSearch, fsoObject.GetExtensionName(filObject.Name), vbTextCompare) > 0 Then

'Check to make sure the file about to be searched is not a barred file if it is don't search the file
If NOT InStr(1, strBarredFiles, filObject.Name, vbTextCompare) > 0 Then

'Initalise the search found variable to flase
blnSearchFound = False

'Initalise the number of matches variable
intNumMatches = 0

'Create the regular expresions object
Set objRegExp = New RegExp

'Set the regular exprsion object to read all cases of the occurance not just the first
objRegExp.Global = True

'Set the regular expression object to ignore case
objRegExp.IgnoreCase = True

'Open the file for searching
Set tsObject = filObject.OpenAsTextStream

'Read in the contents of the file
strFileContents = tsObject.ReadAll

'Read in the title of the file
strPageTitle = Server.HTMLEncode(GetFileMetaTag("<title>", "</title>", strFileContents))

'Read in the description meta tag of the file
strPageDescription = Server.HTMLEncode(GetFileMetaTag("<meta name=""description"" content=""", """>", strFileContents))

'Read in the keywords of the file
strPageKeywords = Server.HTMLEncode(GetFileMetaTag("<meta name=""keywords"" content=""", """>", strFileContents))

'Set the pattern using regular expressions to srip any HTML tags
objRegExp.Pattern = "<[^>]*>"

'Strip HTML tags from the contects of the file to be searched
strFileContents = objRegExp.Replace(strFileContents,"")

'Put the description and the keywords back into the file to be searched
strFileContents = strFileContents & " " & strPageDescription & " " & strPageKeywords

'If the user has choosen to search by phrase
If Request.QueryString("mode") = "phrase" Then

'Set the pattern to search for
objRegExp.Pattern = "\b" & strSearchWords & "\b"

'Search the file for the phrase
Set objMatches = objRegExp.Execute(strFileContents)

'Check to see if the phrase has been found
If objMatches.Count > 0 Then

'Get the number of times the phrase is matched
intNumMatches = objMatches.Count

'If the search is found then set the search found variable to true
blnSearchFound = True
End If

'Else the search is either by all or any words
Else

'If the search is by all words then initialise the search found variable to true
If Request.QueryString("mode") = "allwords" then blnSearchFound = True

'Loop round to search for each word to be searched
For intSearchLoopCounter = 0 to UBound(sarySearchWord)

'Set the pattern to search for
objRegExp.Pattern = "\b" & sarySearchWord(intSearchLoopCounter) & "\b"

'Search the file for the search words
Set objMatches = objRegExp.Execute(strFileContents)

'Check to see if any of the words have been found
If objMatches.Count > 0 Then

'Get the number of times the search word is matched
intNumMatches = intNumMatches + objMatches.Count

'If the search word is found and the search is for any words then set the search found variable to true
If Request.QueryString("mode") = "anywords" then blnSearchFound = True

Else
'If the search word is not found and the search is for all words then set the search found variable back to false as one of the words has not been found
If Request.QueryString("mode") = "allwords" then blnSearchFound = False

End If
Next
End If

'Calculate the total files searched
intTotalFilesSearched = intTotalFilesSearched + 1

'If the page contains no title then Page Title variable the appropriate message to display
If strPageTitle = "" Then strPageTitle = "No Title"

'If the page contains no title then Page Description variable the appropriate message to display
If strPageDescription = "" Then strPageDescription = "There is no description available for this page"

'If the search found variable is true then display the results
If blnSearchFound = True Then

'Calculate the total files found
intTotalFilesFound = intTotalFilesFound + 1

'Check that the file shown is between the the files shown so far and the maximum files to show per page
If intNumFilesShown < (intRecordsPerPage + intFileNum) and intTotalFilesFound > intNumFilesShown Then

'Calculate the number of results shown
intNumFilesShown = intNumFilesShown + 1

End If

'Place the search results into the saerch results array
'Calculate the array position of the results array
intResultsArrayPosition = intResultsArrayPosition + 1

'Set the search results found boolean to true
blnSearchResultsFound = True

'If the file is in the root directory then
If blnIsRoot = True Then

'Place the search results into the search results array
sarySearchResults(intResultsArrayPosition,1) = "<a href=""./" & filObject.Name & """ target=""_self"">" & strPageTitle & "</a>"

'Else it is not in the root directiory
Else
'Place the search results into the search results array
sarySearchResults(intResultsArrayPosition,1) = "<a href=""./" & strFileURL & fldObject.Name & "/" & filObject.Name & """ target=""_self"">" & strPageTitle & "</a>"

End If

'Place the rest of the search results in the search results array
sarySearchResults(intResultsArrayPosition,1) = sarySearchResults(intResultsArrayPosition,1) & vbCrLf & " <br>" & strPageDescription
sarySearchResults(intResultsArrayPosition,1) = sarySearchResults(intResultsArrayPosition,1) & vbCrLf & " <font size=""2"" color=""#00CC99""><br><i>Search Matches " & intNumMatches & "  -  Last Updated " & FormatDateTime(filObject.DateLastModified, VbLongDate) & "  -  Size " & CInt(filObject.Size / 1024) & "kb</i></font>"

'Read in the number of search word matches into the second part of the two dimensional array
sarySearchResults(intResultsArrayPosition,2) = intNumMatches

End If

'Reset the Regular Expression object
Set objRegExp = Nothing

'Close the text stream object
tsObject.Close
End If
End If
Next

'Loop to search through the sub folders within the site
For Each subFldObject In FldObject.SubFolders

'Check to make sure the folder about to be searched is not a barred folder if it is then don't search
If NOT InStr(1, strBarredFolders, subFldObject.Name, vbTextCompare) > 0 Then

'Set to false as we are searching sub directories
blnIsRoot = False

'Get the server path to the file
strFileURL = fldObject.Path & "\"

'Turn the server path to the file into a URL path to the file
strFileURL = Replace(strFileURL, strServerPath, "")

'Replace the NT backslash with the internet forward slash in the URL to the file
strFileURL = Replace(strFileURL, "\", "/")

'Replace the spaces in the URL to the file with Internet friendly %20
strFileURL = Replace(strFileURL, " ", "%20")

'Call the search sub prcedure to search the web site
Call SearchFile(subFldObject)
End If
Next

'Reset server variables
Set filObject = Nothing
Set tsObject = Nothing
Set subFldObject = Nothing
End Sub

'Sub procedure to sort the array using a Bubble Sort to place highest matches first
Private Sub SortResultsByNumMatches(ByRef sarySearchResults, ByRef intTotalFilesFound)

'Dimension variables
Dim intArrayGap 'Holds the part of the array being sorted
Dim intIndexPosition 'Holds the Array index position being sorted
Dim intTempResultsHold 'Temperary hold for the results if they need swapping array positions
Dim intTempNumMatchesHold 'Temperary hold for the number of matches for the result if they need swapping array positions
Dim intPassNumber 'Holds the pass number for the sort

'Loop round to sort each result found
For intPassNumber = 1 To intTotalFilesFound

'Shortens the number of passes
For intIndexPosition = 1 To (intTotalFilesFound - intPassNumber)

'If the Result being sorted hass less matches than the next result in the array then swap them
If sarySearchResults(intIndexPosition,2) < sarySearchResults((intIndexPosition+1),2) Then

'Place the Result being sorted in a temporary variable
intTempResultsHold = sarySearchResults(intIndexPosition,1)

'Place the Number of Matches for the result being sorted in a temporary variable
intTempNumMatchesHold = sarySearchResults(intIndexPosition,2)

'Do the array position swap

'Move the next Result with a higher match rate into the present array location
sarySearchResults(intIndexPosition,1) = sarySearchResults((intIndexPosition+1),1)

'Move the next Number of Matches for the result with a higher match rate into the present array location
sarySearchResults(intIndexPosition,2) = sarySearchResults((intIndexPosition+1),2)

'Move the Result from the teporary holding variable into the next array position
sarySearchResults((intIndexPosition+1),1) = intTempResultsHold

'Move the Number of Matches for the result from the teporary holding variable into the next array position
sarySearchResults((intIndexPosition+1),2) = intTempNumMatchesHold
End If
Next
Next
End Sub

'Function to read in the files meta tags
Private Function GetFileMetaTag(ByRef strStartValue, ByRef strEndValue, ByVal strFileContents)

'Dimension Variables
Dim intStartPositionInFile 'Holds the start position in the file
Dim intEndPositionInFile 'Holds the end position in the file

'Get the start position in the file of the meta tag
intStartPositionInFile = InStr(1, LCase(strFileContents), strStartValue, 1)

'If no description or keywords are found then you may be using http-equiv= instead of name= in your meta tags
If intStartPositionInFile = 0 And InStr(strStartValue, "name=") Then

'Swap name= for http-equiv=
strStartValue = Replace(strStartValue, "name=", "http-equiv=")

'Check again for keywords or description
intStartPositionInFile = InStr(1, LCase(strFileContents), strStartValue, 1)
End If

'If there is a description then the position in file will be over 0
If NOT intStartPositionInFile = 0 Then

'Get the end position of the HTML meta tag
intStartPositionInFile = intStartPositionInFile + Len(strStartValue)

'Get the position in file of the closing tag for the meta tag
intEndPositionInFile = InStr(intStartPositionInFile, LCase(strFileContents), strEndValue, 1)

'Read in the meta tag from the file for the function to return
GetFileMetaTag = Trim(Mid(strFileContents, intStartPositionInFile, (intEndPositionInFile - intStartPositionInFile)))

'If the is no meta tag then the GetFileMetaTag function returns a null value
Else
GetFileMetaTag = ""

End If

End Function
%>

fixman · 17/11/2003, 14:11

Evet, çalışan bir script...
Ama bunun da arkadaşın işine yarayacağını sanmıyorum...

Bakalım ne cevap gelecek...

kernel32 · 01/08/2004, 13:42

insaf diyorum arkadaş.

bişey yapmak istiyorsunda neler var neler yok bilmiyorsun. iyi bende uçak kullanmak istiyorum. (otomobil kullanabiliyorum ya) direksiyonu olan herşeyi sürerim.

sanirim sen dahil bir çok kişi dream veya frontpage da duragan html sayfalar yapmak kadar basit sanıyor istediklerini.

önce PROGRAMCI olman gerekiyor. yani istesdiğin şey bir programlama. sadece kullamış olduğun mediaplayer oynadığın oyunlar program değil. bu web sayfalarıda bir PROGRAMdır. herşeyden önce yapmaya çalıştığın şeyi basite alma

(kusura bakma . gerginim. öyle absürt şeylerle karşılaşmaya başladım ki.)

bak sana tavsiyem. bir ASP kitabı al. php diyenlere bakma. eminim yabancı kalırsın. senin için en kolayı asp.

daha sonra bu işi öğreneceksen illede free sitelerle uğraşma. adamlar milyon dolarlar katrilyonlar istemiyor ya. altı üstü 20 bilemedin 30 milyonuna mal olacak .

biraz temel bilgi edinddikten sonra hazır scriptleri al internetten. (mirc script değil

asp scriptleri. (arama motorları, ziyaretçi defterleri, uyelik sistemleri hatta kocaa portlaleri)

hoopp. öle kopyala yapıştır yok!

adam ne yapmış . ne etmiş iyi bir incele. sonra kendi tasarımın üzerinde kodları uygula. alıp olduğu gibi kullanıp siteni yamalı bohcayada çevirme.

bu arada birak neete uğraşmayı önce bi veritabanını tanı. en azından acces i. zor da değil ya. word excel kullnıyosunda acces niye kullanamayasın ki? veri tabansız interactive bir site düşünülemez.

bir ISS nin yapısı öğren. öle her begendiğin ve istediğin şeyide sayfanda çalıştıramazsın. benim sunucum Jmail desteğini kapatmış. 18 siteye oturdum PERSIST kodları ile değiştirdim.

ondan sonra istediğin dili öğren istediğin veritabanı ve sorgulamayı kullan. istersen mysql kullan ister oracle. hele basit bi başlangıç yap. kedi olmadan fare tutma.

dilim biraz sivri kusura bakma.
ukala değilimdir asla.

bilmemek değil öğrenmemek ayıp elbette. benim kızgınlığım bu işin doğru öğretilmemesi. sana değil sözüm, bu işten ekmek yiyenlere balta vuranlara.

ve SIRF REKLAM UĞRUNA ONUN BUNUN SITESINE ZIYARETCI DEFTERI, COUNTER, MAIL LIST, ARAMA MOTORU. Hataa HAZIR SİTE verip mesleği ayak altına alanlara.

reklamı ucuza getireceğinize kaliteli ve etkin reklam yapında eline klavye geçiren kraldan çok kralcı olmasın.
ŞU SİTEYİ ÖRNEK ALIN BEYLERRR.

5 sene önce bir site fiyatı şimdi 20 site fiyatı oldu. Kendi kendinizi traşlamayın!

MEHMET · 01/08/2004, 13:57

???
bu laflar kimin içindi anlamadım_?_?

15/11/2003, 19:17	#1 (permalink)
asuozkan Üye Üyelik Tarihi: 11/2003 Mesaj: 8	site içi arama motoru site içi arama motoru yapmam gerekiyor.nasil yapildigi konusunda yardimci olabilir misiniz

15/11/2003, 19:34	#2 (permalink)
HunTER ... Üyelik Tarihi: 08/2002 Yer: İstanbul Mesaj: 8,753	1. Sıtede kullanılan sunucu taraflı bı scrıpt dılı varmı? Varsa hangısı (ASP,PHP vs..) 2. Icınde arama yapılacak verı nerde tutuluyor? Web sayfalarında? Verıtabanında? Her ıkısı ve daha fazlası? 3. Krıterler neler? Tek sozcuk arama? Bırden fazla sozcuk arama? 4. Yada sadece google uzerınden arama ısıne yaramazmı?.. Ornegın http://www.google.com.tr/search?q=ph...:www.ceviz.net gıbı Yanı once bunlara bı acıklık getırsen en azından ne yapabılecegın konusunda tavsıye verebılırız.. __________________ Ertuğrul Yıldırım .::. iletisim@eyildirim.org

15/11/2003, 20:55	#4 (permalink)
Sahin Gezgin Üyelik Tarihi: 05/2002 Yer: Kuzey Kutbu Mesaj: 8,336	www.atomz.com gibi özelleştirilebilir free site içi arama motorları işinizi görür mü? __________________ Merdi kıpti şecaat arz ederken sirkatin söyler!

17/11/2003, 12:14	#6 (permalink)
fixman Monster is Live Üyelik Tarihi: 03/2003 Yer: Yemez. Mesaj: 869	__________________ Uyan Berlin, ben eve döndüm...

17/11/2003, 14:11	#8 (permalink)
fixman Monster is Live Üyelik Tarihi: 03/2003 Yer: Yemez. Mesaj: 869	Evet, çalışan bir script... Ama bunun da arkadaşın işine yarayacağını sanmıyorum... Bakalım ne cevap gelecek... __________________ Uyan Berlin, ben eve döndüm...

15/11/2003, 20:31	#3 (permalink)
asuozkan Üye Üyelik Tarihi: 11/2003 Mesaj: 8	istedigim site içi arama.veritabani yok.tek sozcuk veya birden fazla .asp konusunda cok fazla bilgim yok.

17/11/2003, 11:33	#5 (permalink)
asuozkan Üye Üyelik Tarihi: 11/2003 Mesaj: 8	site icinde arama motoru yapmam lazim.www.atomz.com isime yaramaz.tesekkurler

01/08/2004, 13:42	#9 (permalink)
kernel32 Üye Üyelik Tarihi: 08/2004 Mesaj: 2	kedi olmadan fare tutmak :) insaf diyorum arkadaş. bişey yapmak istiyorsunda neler var neler yok bilmiyorsun. iyi bende uçak kullanmak istiyorum. (otomobil kullanabiliyorum ya) direksiyonu olan herşeyi sürerim. sanirim sen dahil bir çok kişi dream veya frontpage da duragan html sayfalar yapmak kadar basit sanıyor istediklerini. önce PROGRAMCI olman gerekiyor. yani istesdiğin şey bir programlama. sadece kullamış olduğun mediaplayer oynadığın oyunlar program değil. bu web sayfalarıda bir PROGRAMdır. herşeyden önce yapmaya çalıştığın şeyi basite alma (kusura bakma . gerginim. öyle absürt şeylerle karşılaşmaya başladım ki.) bak sana tavsiyem. bir ASP kitabı al. php diyenlere bakma. eminim yabancı kalırsın. senin için en kolayı asp. daha sonra bu işi öğreneceksen illede free sitelerle uğraşma. adamlar milyon dolarlar katrilyonlar istemiyor ya. altı üstü 20 bilemedin 30 milyonuna mal olacak . biraz temel bilgi edinddikten sonra hazır scriptleri al internetten. (mirc script değil asp scriptleri. (arama motorları, ziyaretçi defterleri, uyelik sistemleri hatta kocaa portlaleri) hoopp. öle kopyala yapıştır yok! adam ne yapmış . ne etmiş iyi bir incele. sonra kendi tasarımın üzerinde kodları uygula. alıp olduğu gibi kullanıp siteni yamalı bohcayada çevirme. bu arada birak neete uğraşmayı önce bi veritabanını tanı. en azından acces i. zor da değil ya. word excel kullnıyosunda acces niye kullanamayasın ki? veri tabansız interactive bir site düşünülemez. bir ISS nin yapısı öğren. öle her begendiğin ve istediğin şeyide sayfanda çalıştıramazsın. benim sunucum Jmail desteğini kapatmış. 18 siteye oturdum PERSIST kodları ile değiştirdim. ondan sonra istediğin dili öğren istediğin veritabanı ve sorgulamayı kullan. istersen mysql kullan ister oracle. hele basit bi başlangıç yap. kedi olmadan fare tutma. dilim biraz sivri kusura bakma. ukala değilimdir asla. bilmemek değil öğrenmemek ayıp elbette. benim kızgınlığım bu işin doğru öğretilmemesi. sana değil sözüm, bu işten ekmek yiyenlere balta vuranlara. ve SIRF REKLAM UĞRUNA ONUN BUNUN SITESINE ZIYARETCI DEFTERI, COUNTER, MAIL LIST, ARAMA MOTORU. Hataa HAZIR SİTE verip mesleği ayak altına alanlara. reklamı ucuza getireceğinize kaliteli ve etkin reklam yapında eline klavye geçiren kraldan çok kralcı olmasın. ŞU SİTEYİ ÖRNEK ALIN BEYLERRR. 5 sene önce bir site fiyatı şimdi 20 site fiyatı oldu. Kendi kendinizi traşlamayın!

01/08/2004, 13:57	#10 (permalink)
MEHMET READ ONLY Üyelik Tarihi: 05/2003 Yer: MERSİN Mesaj: 3,686	??? bu laflar kimin içindi anlamadım_?_?

Seçenekler
Yazdırmaya Uygun Sayfa Sayfayı E-posta İle Gönder

Benzer Konular
Konu	Konuyu açana göre	Forum	Cevap	En Son Mesaj
Detaylı bir site içi arama motoru	Sahin	PHP	121	01/11/2006 22:44
site içi arama motoru	doganaydin	PHP	10	15/06/2005 01:18
Site içi arama motoru	mericok	Web Tasarım	3	25/05/2005 18:16
Site içi arama motoru	yumert	PHP	2	12/02/2005 11:51
site içi arama motoru	chyenne	PHP	10	30/06/2004 12:41